Linguistics 567: Knowledge Engineering for NLP

Lab 8 Due 2/29

Navigation

• Baseline test suite
• Background
• Basic approach
• Implementation
  • Preliminaries
  • Define tense and aspect values
  • Associate tense and aspect with appropriate forms
    • lexically specified
    • inflection
    • auxiliary
    • particle
  • Constrain the context
• Write up

Run a baseline test suite

Before making any changes to your grammar for this lab, run a baseline test suite instance. If you decide to add items to your test suite for the material covered here, consider doing so before modifying your grammar so that your baseline can include those examples. (Alternatively, if you add examples in the course of working on your grammar and want to make the snapshot later, you can do so using the grammar you turned in for Lab 7.)

Background

Basic definitions

• eventuality: a cover term for the things described by verbal predicates, specifically, both events and states
  
• tense: relation of eventuality to speech time
• grammatical aspect: conveys information about the viewpoint on an eventuality
  • imperfective: view of the event from the inside (no boundaries relevant)
    • continuous (specifically: imperfect, progressive), 'I am eating'
    • generic, 'Rabbits eat peas'
    • habitual, 'I eat yogurt (every day)'
      Note: Habitual as a subcategory of imperfective is only one possible analysis. Alternatively, habitual might be analyzed as a separate form of aspect or even as an additional feature of the event variable.
  • perfective: view of the event from the outside (as a completed whole) (specifically: perfective, aorist), 'I ate the peas'
• situation aspect: provides information about the type of eventuality -- We are not dealing with this.
  • state, e.g., like, believe
  • process (activity), e.g., read, run, sit
  • process + culmination (accomplishment, achievement), e.g., eat an apple, run to the store, reach the summit, arrive
• perfect: relates a state to a previous eventuality -- We are not dealing with this. 
  • present perfect, 'he has eaten' (he is in a state related to a past completed event of eating)
  • past perfect, 'he had eaten' (he was in a state related to a past (in relation to the state) completed event of ...)
  • future perfect, 'he will have eaten' (he will be in a state related to a past (in relation to the state) completed event of ...)
• mood: relates to the attitude of the speaker. Mood covers a lot of territory including conditional, subjunctive and irrealis. In some languages, future may not be marked as a tense but instead may be irrealis mood. -- We will not deal with mood and won't worry about the future as tense vs. mood distinction.

Common sources

There are many sources of tense and/or grammatical aspect, i.e., possible forms of contributing elements:

• lexically specified on the verb: a reasonable analysis for Slavic-type languages that have perfective/imperfective verb pairs.
• inflection on the verb
• auxiliary + verb: the form of the verb is restricted, the auxiliary may take inflection
• (verb) + particle: the form of the verb is unrestricted, the particle cannot be inflected
• adverbs: we will deal with these only if they are the primary way that tense (or aspect) is conveyed
• portmanteau morphemes: one form may convey a combination of characteristics, for example
  • tense and aspect as with French imparfait (past tense + imperfective aspect)
  • tense and/or aspect and agreement as with English 3sg present tense forms
• inferred from context or other sentential elements (not explicitly tense or grammatical aspect) -- We are not dealing with this.

Basic Approach

• Define values for the features TENSE and ASPECT, reflecting the distinctions in the language.
• Associate TENSE and ASPECT values with the contributing forms.
• Constrain the context for those elements as necessary.

Implementation Specifics

Preliminaries

Replace the lexical type hierarchy for finite and nonfinite verbs with lexical rule types (if not already done).

For English, I expanded the hierarchy under form, adding nonfin (nonfinite) with subtypes base (for infinitival forms) and prespart (for present participle forms):

nonfin := form.
base := nonfin.
prespart := nonfin.

Then I wrote lexical rules for finite and nonfinite verbs that specify the FORM values. These lexical rules will function as supertypes for lexeme to word rules and so inherit from lexeme-to-word-rule defined in matrix.tdl.

finite-verb-lex-rule := lexeme-to-word-rule &
   [ DTR.SYNSEM.LOCAL.CAT.HEAD verb & [FORM fin]].

nonfinite-verb-lex-rule := lexeme-to-word-rule & 
   [ DTR.SYNSEM.LOCAL.CAT.HEAD verb & [FORM nonfin]].

I also wrote a rule that defines English infinitival forms (base).

base-verb-lex-rule := nonfinite-verb-lex-rule &
  [ DTR.SYNSEM.LOCAL.CAT.HEAD.FORM base ].

Define tense and aspect values

Define values for the features TENSE and ASPECT in a hierarchy. The specific values possible for these features need to be defined in klingon.tdl. The TENSE and ASPECT features themselves are defined in matrix.tdl as features of the type tam (which is itself the value of the feature E, declared for the type event, i.e., the value of INDEX on verbs). Each particular language may have a different set of values and a different hierarchy. Some languages have more general, and some more specific, contrasts, e.g., [past]/[nonpast] vs. [[farpast/past]/recentpast]/[present/nearfuture/...].

nonfuture := tense.
nonpast := tense.
past := nonfuture.
present := nonpast & nonfuture.
future := nonpast.

perfective := aspect.
imperfective := aspect.
progressive := imperfective.
nonprogressive := imperfective.
habitual := nonprogressive.
generic := nonprogressive. 

Associate tense and aspect with appropriate forms

Lexically specified

General approach: If aspect is defined on the lexical entries themselves define the aspect directly on the verbs.

• Define lexical types for the aspect classes with the appropriate ASPECT values designated.
• Cross-classify these lexical types as necessary with your existing subtypes of verb-lex.
  
• Lexical entries then inherit from the appropriate lexical types.

Inflection

If tense and/or aspect is conveyed by inflection on the verb:

General approach: Define the value of tense/aspect in the lexical-rule that licenses the verb.

• Write lexical-rules that define the verb form(s).  Build a hierarchy of lexical rule types from which instances of lexical rules can inherit.
  
  For English, I wrote a present tense rule and a past tense rule. The past tense rule inherits a finite FORM value from the type finite-verb-lex-rule. It additionally needs to inherit from inflecting-lex-rule since it will be associated with an inflectional rule in irules.tdl.  This rule adds the specification that the verb is not an auxiliary (AUX -) and that the values of TENSE and ASPECT in the semantic content (CONT) are 'past' and 'perfective', respectively. 


In english.tdl:

past-tense-lex-rule := finite-verb-lex-rule & inflecting-lex-rule &
  [ DTR.SYNSEM.LOCAL [ CAT.HEAD.AUX -,
    		       CONT.HOOK.INDEX.E [ TENSE past,
					   ASPECT perfective ] ] ].

The present tense rule is similar but only constrains the tense of the verb. This will function as a supertype for instances of present tense verb rules with different agreement constraints (since English distinguishes 3sg from non-3sg in present tense verbs).

present-tense-lex-rule := finite-verb-lex-rule &
[ DTR.SYNSEM.LOCAL.CONT.HOOK.INDEX.E.TENSE present ].



• Write the associated orthographic rules in irules.tdl that capture the inflection (or lrules.tdl for forms with no inflection).
  As an example of an orthographic (inflectional) rule, I wrote this (admittedly incomplete) past tense rule for English:
  
  In irules.tdl:

  past-tense-verb := 
  %suffix (!e !eed) (e ed)
  past-verb-lex-rule.
  

• If tense or aspect is introduced through a portmanteau morpheme, add semantic information to the rules, e.g., agreement rules, that are already in the grammar.  You might find it convenient to cross-classify lexical rule types for e.g., agreement and tense/aspect, so that you get a 1sg-past-lex-rule and a 1sg-present-lex-rule, which both inherit from a 1sg-verb-lex-rule which puts in the information about the PNG of the subject.  Similarly, 1sg-past-lex-rule and the other past tense lex rules would inherit from the type past-tense-lex-rule which would fill in the TENSE information.




For English, I added tense and aspect information to the rules that define the agreement+tense+aspect (present tense) verb forms, e.g., "He walks", "I/you/we/they walk". Note that these rules are instances of subtypes of present-tense-lex-rule. (In English, the full cross-classification doesn't make sense, as the agreement information is only marked in present tense, and only makes a two-way distinction even there.)


3sg-present-verb-lex-rule := present-tense-lex-rule & inflecting-lex-rule & 
  [ DTR.SYNSEM.LOCAL [ CAT [ HEAD.AUX -,
                             VAL.SUBJ < [ LOCAL.CONT.HOOK.INDEX.PNG.PERNUM 3sg ] > ],
		       CONT.HOOK.INDEX.E.ASPECT nonprogressive ] ].

non3sg-present-verb-lex-rule := present-tense-lex-rule & constant-lex-rule &
  [ DTR.SYNSEM.LOCAL [ CAT [ HEAD.AUX -,
			     VAL.SUBJ < [ LOCAL.CONT.HOOK.INDEX.PNG.PERNUM non3sg ] > ],
		       CONT.HOOK.INDEX.E.ASPECT nonprogressive ] ].

These rules have the following associated irules and lrules:

In irules:

3sg-present-verb :=
%suffix (!s !ss) (s ses)
3sg-present-verb-lex-rule. 

In lrules:

non3sg-present-verb := non3sg-present-verb-lex-rule.

• If there are stacked affixes there will need to be several lexical rules appropriately constrained (see Lab 5, Lexical Rules).

Auxiliary

If tense and/or aspect is conveyed by an auxiliary plus verb form:

General approach: Define the verb forms that are required with the auxiliary including the aspect (or tense, if appropriate) they contribute. Define the auxiliary, including the tense (and/or aspect as appropriate) specifying the required verb type as a complement of the auxiliary. The auxiliary is treated as a head and the verb form as a complement. Their combination is then licensed by the grammar's head-complement rule.

• Write lexical rules and associated orthographic rules (irules or lrules, if appropriate) for the verbal form(s) required in auxiliary constructions.

For English, I added the present participle form that also contributes progressive aspect.

In english.tdl:

presparticiple-verb-lex-rule := nonfinite-verb-lex-rule & inflecting-lex-rule &
  [ DTR.SYNSEM.LOCAL[ CAT.HEAD [AUX -, FORM prespart ],
		      CONT.HOOK.INDEX.E.ASPECT progressive ] ]

In irules.tdl:


presparticiple-verb :=
%suffix (!e !eing) (e ing)
presparticiple-verb-lex-rule.

• Define a lexical type for the auxiliary. The auxiliary introduces no relation of its own and the main verb/VP is treated as the complement of the auxiliary (inherited from trans-first-arg-raising-lex-item-2). The subject of the auxiliary is the subject of the verb/VP (inherited from subj-raising-aux). (You may already have such an auxiliary in your grammar.)

  
  For English, I defined the following type, specifying the form of the compliment to be a present participle (prespart). This analysis asserts that progressive aspect in English is introduced by the present participle. Alternatively, aspect might be introduced by the auxiliary itself. In that case, the type for the auxiliary would need to specify the aspect.

  be-aux := subj-raise-aux & trans-first-arg-raising-lex-item-2 &
    [ INFLECTED +,
      ARG-ST < [ ], [LOCAL.CAT.HEAD.FORM prespart ] > ].

  Note that semantically contentful auxiliaries (like can) should instead inherit from trans-first-arg-raising-lex-item-1.

• Write inflectional rules and lexical rules for the auxiliary forms or add inflected forms to the lexicon.

  
  For English, I added past and present tense 'be' verb forms to the lexicon. The following are two of several such entries. Note that non-auxiliary uses of the verb would require a separate entries in the lexicon. 

  be-aux-am := be-aux &
    [ STEM < "am" >,
      SYNSEM.LOCAL [ CAT.VAL.SUBJ < [ LOCAL.CONT.HOOK.INDEX.PNG.PERNUM 1sg ] >,
                     CONT.HOOK.INDEX.E.TENSE present ] ] .
  
  be-aux-was := be-aux &
    [ STEM < "was" >,
      SYNSEM.LOCAL [ CAT.VAL.SUBJ < [ LOCAL.CONT.HOOK.INDEX.PNG.PERNUM 1+3sg ] >,
                     CONT.HOOK.INDEX.E.TENSE past ] ] .
  

Particle

If tense and/or aspect is conveyed by an element that looks like a particle, the implementation depends on the analysis of the particle-like element.

• If the element is invariant in form and cannot be separated from the verb: Treat it as inflection.
• If the element constrains the form of the associated verb or otherwise acts as a head: Treat it as an auxiliary.
• If the element is invariant and acts as a sentential modifier: Treat it as a modifier that adds no additional relation but constrains the tense and/or aspect on the verb.
• If the element adds tense or aspect in addition to an additional event relation: Treat it as a temporal adverb. Specify the tense or aspect values of the adverb's INDEX. Additionally, constrain the tense or aspect of the modified element to identify with that of the adverb.

Constrain the context for tense and/or aspect

What is necessary to appropriately constrain tense and aspect depends on the particular language.

Two typical scenarios:

• Aspectual construction restricted to particular class of verbs:

  One possible analysis of English restricts progressive to non-stative verbs, ruling out constructions like 'He is knowing the answer'. One way to constrain progressive constructions from occurring with stative verbs:

  • Define another tam feature value (boolean valued feature STATIVE) to record whether the verb is stative.
  • Create verb supertypes that include this feature: STATIVE + for stative verbs, STATIVE - for non-statives.
  • Have all verbs in the lexicon inherit from one of these supertypes.
  • Make be-aux sensitive to this feature by constraining the complement of the auxiliary to be STATIVE -.

  be-aux := subj-raise-aux & trans-first-arg-raising-lex-item-2 &
    [ INFLECTED +,
      ARG-ST < [ ],[ LOCAL [ CAT.HEAD.FORM prespart,
                             CONT.HOOK.INDEX.E.STATIVE - ] ] > ].
      

• Tense restricted to particular aspects:

  It is widely accepted that perfective aspect is cognitively incompatible with present tense since (roughly) present tense is punctual and perfective aspect requires that an event be viewed as a whole (compete) and if it is complete it is not happening in the present moment. Different languages handle this cognitive dissonance differently.

  For example, one possible analysis of English assumes that all present tense forms are imperfective therefore there are no present perfective constructions. The easiest way to implement this constraint is to define all present tense forms as imperfective. This is what I have done in the examples above. 

  • Progressive constructions require a present participle which is defined as progressive.
  • The present tense lexical rules define the verb to be non-progressive which is a subtype of imperfective.

  Alternatively, in Russian, there are present tense forms of perfective verbs. However, these constructions always result in a future tense interpretation. There are several possible analyzes of this phenomenon. Although there are certainly other viable approaches, I suggest treating the present tense inflection on imperfectives and perfectives as distinct but homophonous forms.

  • Define two distinct lexical rules, one specifying that the verb is imperfective and the tense is present, the other specifying the verb as perfective and the tense as future.
  • Each of these lexical rules will have an orthographic rule associated with it that defines the same string.

Write up

Your write up should address the following phenomena. For each, be sure to include examples in IGT format from your test suite to illustrate your points. (Emily should be able to parse the examples as given to see for herself what your grammar is doing.)

1. Describe the ways in which tense and aspect is marked in your language and which forms you chose to implement in your grammar.
2. As best you can, describe the meanings associated with each tense/aspect distinction you implement.  (There might not be much information in your grammar on this point---the author may have just labeled the tense or aspects---but if you can find something, please report it.  We're curious because the terminology is so varied across different works.)
   
3. Describe ways in which your language constrains the tense and aspect elements you implemented.
4. Describe how you implemented tense and aspect in your grammar, including at least:
   • What hierarchies did you implement? Why?
   • What tense and aspect forms did you implement? How?
   • How did you constrain the tense and aspect elements you implemented?
5. What difficulties did you encounter (especially if you haven't yet been able to solve them)?
6. Document what happened when you tested you implementation of tense and aspect, and anything you had to change in your grammar to get them working properly.

Submit your assignment

• Create a tarball of your grammar (don't leave out the lkb subdirectory or irregs.tab etc.), your tsdb directory, and your write up. Please have the grammar files in the top level directory rather than inside a subdirectory such as matrix or lab8 or mygrammar. The best way to create the tarball (so that it unpacks most easily when I download from CollectIt) is to cd into the directory containing your lab and do:

  tar czf lab8.tgz *

  (When I download your submission from CollectIt, it comes in a directory named with your UWNetID. The above method avoids extra directory structure inside that directory.)

• Upload the tarball to CollectIt